home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr14
/
dndprogs.zip
/
MEG
< prev
next >
Wrap
Text File
|
1993-04-01
|
34KB
|
3,010 lines
Monster Encounter Generator for use with GW-Basic
By Jim Vassilakos <jimv@ucrmath.ucr.edu>
Public Domain: Molest @ Will * September 1991
1. Introduction
Several interesting programs have recently been posted to RGF
by a variety of folks more computer competent than myself.
Nevertheless, I'm gonna throw in yet another for those of
you who aren't too ashamed of Basic and who have access to
a computer with GW-Basic. The program is called MEG.BAS (Monster
Encounter Generator), and it's mainly for use with AD&Dv1.
The general idea is that you type the name of a monster that
it recognizes, and it outputs various things to help you run
the encounter.
The program was written in GW-Basic 3.20 on an IBM-PC compatible.
I suspect that it will run using PC Basic and Basica as well
as with various other versions of GW-Basic, but until you try it,
who really knows?
The program relies on an ASCII data file from which it reads
the information it knows about various monsters. This "monster
file" (mfile.a) currently contains over two hundred monsters
gleaned from the pages of the Monster Manuals and Folio. The
program is public domain, so feel free to use it however you
see fit. To find out how it works, just type "help" at the
first prompt, and you should be able to figure things out from
there.
All comments, etc. are welcome. If you need help getting it
set-up, just send me email, and I'll help if I can.
2. Sample Runs
The following are two sample runs just to illustrate what
the program does before you go to the trouble to get it
working on your computer. The first shows you the output
of an encounter with the dreaded "Purple Worm".
Monster: Purple Worm
Ref: MM1 p80
Thaco: 8
AC: 6
D/A: 2d12 2d4
# 1 HP = 73 XP = 6360 # 2 HP = 72 XP = 6340
Total XP = 12700
Treasure...
gold: 2000
gems: 6
gem values: 100 50 100 50 50 500 = 850
grand total value (excluding magic): 2850 gp
XP+XP(TT) = 15550
Maps and Magic
Potions: 1
Miscellaneous Magic: 1
This next example shows you how to skip the monster
encounter all together and get straight to treasure
generation if that's what you're interested in. In this
example, the user is generating treasure for a Red Dragon,
treasure types H, S, & T.
Monster: $hst
Treasure...
electrum: 25000
gold: 31000
gems: 56
jewelry: 25
gem values: 500 50 1000 10 50 50 50 5000 10 50
100 500 50 10 500 10 50 10 50 50
100 100 1000 50 500 50 100 50 500
500 500 1000 10 500 50 10 500 50
10 100 100 500 10 500 100 100 100
50 100 1000 500 10 10 10 50 500 = 17420
jewelry values: 300 3000 1700 4000 5000 8000 1200
1000 6000 200 700 7000 1400 5000
8000 1500 1000 6000 2000 3000 2100
1200 1300 700 5000 = 76300
grand total value (excluding magic): 137220 gp
Maps and Magic
Potions: 3
3. GW-Basic code for MEG.BAS
What follows in this section is the code for the
program itself. Feel free to modify it as you feel
best suits your game.
3 DIM D(27,8,4)
4 DIM T(17)
5 DIM G(7,3)
6 DIM J(8,5)
7 DIM MP(27)
8 DIM EX(15)
9 RANDOMIZE INT(TIMER/2)
10 KEY OFF:CLS
20 PRINT"Monster Encounter Generator for use with GW-Basic"
30 PRINT" By Jim Vassilakos <jimv@ucrmath.ucr.edu>"
35 PRINT"Public Domain: Molest @ Will * September 1991"
36 GOSUB 1100
40 PRINT
50 INPUT"Monster: ",M$
55 IF LEFT$(M$,1)<>"$"GOTO 60
57 TT$=RIGHT$(M$,LEN(M$)-1)
58 GOSUB 1200
59 GOTO 40
60 IF M$="help" GOTO 500
70 IF M$="list" GOTO 600
80 IF M$="more help" GOTO 1000
90 IF M$="end" GOTO 9998
100 REM Find
110 OPEN "i",1,"mfile.a"
120 INPUT#1,N$
130 IF M$=N$ GOTO 200
140 INPUT#1,Z$,Z$,Z$,Z$,Z$,Z$,Z$,Z$
150 IF EOF(1)=-1 GOTO 400
160 GOTO 120
200 REM Found
210 INPUT#1,RE$,NA$,TT$,TH$,AC$,DA$,H$,X$
220 CLOSE
230 REM print the basics
232 PRINT"Ref: "RE$
235 PRINT"Thaco: "TH$
240 PRINT"AC: "AC$
245 PRINT"D/A: "DA$
246 IF INSTR(TT$,"+")=0 GOTO 250
247 PRINT"Ind-TT: "RIGHT$(TT$,LEN(TT$)-INSTR(TT$,"+"))
248 TT$=LEFT$(TT$,INSTR(TT$,"+")-1)
250 REM Interpret Range Vaules
255 Z8$=NA$:GOSUB 700
260 N1=Z5:N2=Z6:N3=Z7
265 Z8$=H$:GOSUB 700
270 H1=Z5:H2=Z6:H3=Z7
275 Z1=N1:Z2=N2:Z3=N3:GOSUB 800
280 N=Z8
285 Z5=INSTR(X$,"+")
290 Z6=INSTR(X$,"/")
295 X1=VAL(LEFT$(X$,Z5-1))
298 X2=VAL(MID$(X$,Z5+1,Z6-Z5-1))
300 REM Output
305 PRINT
310 FOR Z7=1 TO N
315 Z1=H1:Z2=H2:Z3=H3:GOSUB 800
320 ZH=Z8
325 ZX=X1+(X2*ZH)
330 ZY=ZY+ZX
332 IF Z7 MOD 2 = 0 GOTO 336
333 PRINT TAB(1)"#"Z7;TAB(8)"HP ="ZH;TAB(18)"XP ="ZX;
334 IF Z7=N THEN PRINT
335 GOTO 340
336 PRINT TAB(32)"#"Z7;TAB(39)"HP ="ZH;TAB(49)"XP ="ZX
340 NEXT Z7
345 PRINT:PRINT"Total XP ="ZY
350 GOSUB 1200
395 ZY=0:GOTO 40
400 REM No Found
410 CLOSE
420 PRINT"There be no such creature, at least according to"
430 PRINT"this lame program. Try try again..."
440 GOTO 40
500 REM Help
505 PRINT
510 PRINT"Encounter Generator is the obnoxious sort of program"
520 PRINT"that refuses to do very much, even when you beg and"
530 PRINT"plead. The basic idea is that you enter the name of"
540 PRINT"a well known AD&Dv1 monster, and it spits out various"
550 PRINT"bits of information, incuding hit points per creature,"
560 PRINT"experience yield, and most important, treasure."
570 PRINT
580 PRINT"To get a list of monsters the program recognizes,"
590 PRINT"type 'list' at the 'Monster' prompt. To exit out"
591 PRINT"of the program, type 'end'. To get more information"
592 PRINT"about this program, type 'more help'. To generate"
593 PRINT"treasure, type '$' followed by the treasure types to be"
594 PRINT"generated (in lower case, i.e. '$hst' for TT's H,S,&T)."
595 PRINT
596 PRINT" * * * Have A Nice Day * * *"
597 PRINT:PRINT" ...and don't forget... Kittybalz!"
598 GOTO 40
600 REM List
605 PRINT
610 OPEN "i",1,"mfile.a"
615 Z1=0
620 INPUT#1,N$
630 INPUT#1,Z$,Z$,Z$,Z$,Z$,Z$,Z$,Z$
640 PRINT N$
650 IF EOF(1)=-1 GOTO 690
655 Z1=Z1+1
656 IF Z1 MOD 20 <> 0 THEN GOTO 620
660 PRINT:INPUT"--- More --- ",ZZ$
665 PRINT
670 GOTO 620
690 CLOSE
695 GOTO 40
700 REM std range interpreter routine
710 Z1=INSTR(Z8$,"d")
720 IF Z1<>1 GOTO 740
730 Z5=1:GOTO 750
740 Z5=VAL(LEFT$(Z8$,Z1-1))
750 Z2=INSTR(Z8$,"+")
755 Z3=INSTR(Z8$,"-")
760 Z4=Z2+Z3
765 IF Z4<>0 GOTO 784
780 Z7=0:Z6=VAL(RIGHT$(Z8$,LEN(Z8$)-Z1))
782 GOTO 795
784 Z6=VAL(MID$(Z8$,Z1+1,Z4-Z1-1))
786 Z7=VAL(RIGHT$(Z8$,LEN(Z8$)-Z4))
790 IF MID$(Z8$,Z4,1)="-" THEN Z7=-Z7
795 RETURN
800 REM Standard Randomizing Routine
825 Z8=0
830 FOR Z4=1 TO Z1
835 Z5=INT(RND*Z2)+1
840 Z8=Z8+Z5
845 NEXT Z4
850 Z8=Z8+Z3
860 RETURN
900 REM Any MorM Routine
910 FOR XX=1 TO EX(11)
915 R=INT(100*RND(1))+1
920 Y=8
925 IF R>20 THEN Y=9
930 IF R>35 THEN Y=10
935 IF R>40 THEN Y=11
940 IF R>45 THEN Y=12
945 IF R>60 THEN Y=13
950 IF R>75 THEN Y=14
955 IF R>86 THEN Y=15
960 IF EX(12)=0 GOTO 985
962 OK=1
965 FOR Z=1 TO EX(12)
970 IF EX(Z)=Y THEN OK=0
975 NEXT Z
980 IF OK=0 THEN GOTO 915
985 T(Y)=T(Y)+1
990 NEXT XX
995 RETURN
1000 REM More Help
1002 PRINT
1003 PRINT"Oh boy....
1004 PRINT"This is where the programer gets to pontificate"
1006 PRINT"about life, the multiverse, and liposuction."
1008 PRINT
1010 PRINT"MEG (Monster Encounter Generator, i.e. this"
1012 PRINT"program) has many minor foibles which you may"
1014 PRINT"or may not want to be made aware of. The first"
1016 PRINT"is that it won't help you role-play, although"
1018 PRINT"for you roll-players out there, this might not"
1020 PRINT"be viewed as problem (``Role-playing? What's he"
1021 PRINT"talking about?'').
1022 PRINT""
1024 PRINT"The program relies on a monster file, 'mfile.a',"
1026 PRINT"which you may add to, change, or whatever. Each"
1028 PRINT"monster takes nine lines of the file: name, ref,"
1030 PRINT"# appearing, treasure type, thaco, armor class,"
1032 PRINT"damage/attack, hitpoint range, experience formula."
1034 PRINT"This file should have no blank lines."
1036 PRINT:INPUT"",ZZ$
1038 PRINT"Where large groups of monsters are concerned, MEG"
1040 PRINT"does not account for high hit-die leaders. It won't"
1042 PRINT"figure out the treasure of individuals in a group."
1044 PRINT"Nor is it flexible enough to account for monsters"
1046 PRINT"with multiple hit dice (i.e., Whipweed from Fiend"
1048 PRINT"Folio)."
1050 PRINT
1052 PRINT"Because the output often has a tendancy to scroll"
1054 PRINT"off the screen, one of the best ways to use MEG is"
1056 PRINT"to send its output to a file (gwbasic meg > file)."
1058 PRINT"Also, remember that your input at the 'Monster'"
1060 PRINT"prompt is case-sensitive."
1062 PRINT""
1064 PRINT"Feel free to edit both MEG and mfile.a as you see"
1066 PRINT"fit. And if you decide to do any substantial"
1068 PRINT"upgrading, please email me a copy of the revised"
1070 PRINT"work. MEG is shareware, so don't even try to send"
1072 PRINT"me money, or I'll sneak into your house on a"
1074 PRINT"moonless night and do evil things to your cat."
1078 PRINT:PRINT" * Meow?! *"
1095 GOTO 40
1100 REM load d(x,y,z)
1110 FOR X=1 TO 26
1115 FOR Y=1 TO 7
1120 FOR Z=1 TO 3
1130 READ D(X,Y,Z)
1140 NEXT Z
1145 NEXT Y
1150 NEXT X
1155 REM load g(x,y)
1160 FOR B=1 TO 6
1165 READ G(B,1):READ G(B,2)
1168 NEXT B
1169 REM load j(x,y)
1170 FOR C=1 TO 7
1172 FOR E=1 TO 4
1174 READ J(C,E)
1176 NEXT E
1178 NEXT C
1180 REM load mp(x)
1182 FOR X=1 TO 26
1184 READ MP(X)
1186 NEXT X
1190 RETURN
1200 REM Treasure Type Routine
1205 PRINT
1206 IF TT$<>"0" GOTO 1210
1207 PRINT:RETURN
1210 FOR ZZ=1 TO 16
1211 T(ZZ)=0
1212 NEXT ZZ
1215 L=LEN(TT$)
1220 FOR Q=1 TO L
1225 X=ASC(MID$(TT$,Q,1))-96
1230 FOR Y=1 TO 7
1240 R=INT(100*RND(1))+1
1250 IF R>D(X,Y,1) GOTO 1318
1255 N2=0
1260 FOR A=1 TO D(X,Y,2)
1270 N1=INT(D(X,Y,3)*RND(1))+1
1280 N2=N2+N1
1290 NEXT A
1300 IF Y<5 AND (X<10 OR X>14) THEN N2=N2*1000
1310 IF Y=5 AND (X<10 OR X>14) THEN N2=N2*100
1315 T(Y)=T(Y)+N2
1318 NEXT Y
1320 REM Maps or Magic?
1322 R=INT(100*RND(1))+1
1324 IF R>MP(X) GOTO 1395
1326 IF X<>1 GOTO 1330
1327 EX(11)=3:EX(12)=0:GOSUB 900
1329 GOTO 1395
1330 IF X<>2 GOTO 1334
1331 EX(11)=1:EX(12)=5:EX(1)=1:EX(2)=2:EX(3)=3
1332 EX(4)=4:EX(5)=5:GOSUB 900
1333 GOTO 1395
1334 IF X<>3 GOTO 1338
1335 EX(11)=2:EX(12)=0:GOSUB 900
1337 GOTO 1395
1338 IF X<>4 GOTO 1342
1339 EX(11)=2:EX(12)=0:GOSUB 900
1340 T(8)=T(8)+1
1341 GOTO 1395
1342 IF X<>5 GOTO 1346
1343 EX(11)=3:EX(12)=0:GOSUB 900
1344 T(9)=T(9)+1
1345 GOTO 1395
1346 IF X<>6 GOTO 1350
1347 EX(11)=3:EX(12)=2:EX(1)=14:EX(2)=15:GOSUB 900
1348 T(8)=T(8)+1:T(9)=T(9)+1
1349 GOTO 1395
1350 IF X<>7 GOTO 1354
1351 EX(11)=4:EX(12)=0:GOSUB 900
1352 T(9)=T(9)+1
1353 GOTO 1395
1354 IF X<>8 GOTO 1358
1355 EX(11)=4:EX(12)=0:GOSUB 900
1356 T(8)=T(8)+1:T(9)=T(9)+1
1357 GOTO 1395
1358 IF X<>9 GOTO 1362
1359 EX(11)=1:EX(12)=0:GOSUB 900
1361 GOTO 1395
1362 IF X<>19 GOTO 1366
1363 T(8)=T(8)+(INT(4*RND(1))+1)+(INT(4*RND(1))+1)
1365 GOTO 1395
1366 IF X<>20 GOTO 1370
1367 T(9)=T(9)+INT(4*RND(1))+1
1369 GOTO 1395
1370 IF X<>21 GOTO 1374
1371 T(10)=T(10)+1:T(11)=T(11)+1:T(12)=T(12)+1
1372 T(13)=T(13)+1:T(14)=T(14)+1:T(15)=T(15)+1
1373 GOTO 1395
1374 IF X<>22 GOTO 1378
1375 T(10)=T(10)+2:T(11)=T(11)+2:T(12)=T(12)+2
1376 T(13)=T(13)+2:T(14)=T(14)+2:T(15)=T(15)+2
1377 GOTO 1395
1378 IF X<>23 GOTO 1382
1379 T(16)=T(16)+1
1381 GOTO 1395
1382 IF X<>24 GOTO 1386
1383 T(12)=T(12)+1
1384 T(8)=T(8)+1
1385 GOTO 1395
1386 REM TT=Z
1387 EX(11)=3:EX(12)=0:GOSUB 900
1395 NEXT Q
1400 PRINT"Treasure..."
1410 PRINT
1418 IF T(1)=0 GOTO 1428
1420 PRINT "copper:";T(1)
1428 IF T(2)=0 GOTO 1438
1430 PRINT "silver:";T(2)
1438 IF T(3)=0 GOTO 1448
1440 PRINT "electrum:";T(3)
1448 IF T(4)=0 GOTO 1458
1450 PRINT "gold:";T(4)
1458 IF T(5)=0 GOTO 1468
1460 PRINT "platinum:";T(5)
1468 IF T(6)=0 GOTO 1478
1470 PRINT "gems:";T(6)
1478 IF T(7)=0 GOTO 1487
1480 PRINT "jewelry:";T(7)
1487 N2=0:N4=0
1488 IF T(6)=0 GOTO 1598
1490 PRINT
1500 PRINT"gem values: ";
1505 N2=0
1510 FOR F=1 TO T(6)
1520 R1=INT(100*RND(1))+1
1530 FOR H=1 TO 6
1540 IF R1>G(H,1) THEN N1=G(H,2)
1550 NEXT H
1555 IF POS(0)<55 GOTO 1560
1556 PRINT:PRINT SPACE$(12);
1560 PRINT N1;
1570 N2=N2+N1
1580 NEXT F
1590 PRINT"=";N2
1598 IF T(7)=0 GOTO 1700
1600 PRINT:PRINT"jewelry values: ";
1610 FOR F=1 TO T(7)
1620 R1=INT(100*RND(1))+1
1630 FOR H=1 TO 7
1640 IF R1>J(H,1) THEN I=H
1650 NEXT H
1652 N3=0
1655 FOR K=1 TO J(I,2)
1660 N1=INT(J(I,3)*RND(1))+1
1665 N3=N3+N1
1670 NEXT K
1675 N3=N3*J(I,4)
1677 IF POS(0)<55 GOTO 1680
1678 PRINT:PRINT SPACE$(16);
1680 PRINT N3;
1685 N4=N4+N3
1688 NEXT F
1690 PRINT"=";N4
1700 PRINT:PRINT"grand total value (excluding magic):";
1710 N5=(T(1)/200)+(T(2)/20)+(T(3)/2)+T(4)+(T(5)*5)+N2+N4
1720 PRINT N5;"gp"
1725 IF LEFT$(M$,1)="$" GOTO 1800
1730 PRINT"XP+XP(TT) ="N5+ZY
1800 REM Output Magic Item Summary
1805 ZZ=T(8)+T(9)+T(10)+T(11)+T(12)+T(13)+T(14)+T(15)+T(16)
1806 IF ZZ=0 GOTO 1990
1808 PRINT:PRINT"Maps and Magic":PRINT
1810 IF T(16)=0 GOTO 1814
1812 PRINT"Maps:"T(16)
1814 IF T(8)=0 GOTO 1820
1815 PRINT"Potions:"T(8)
1820 IF T(9)=0 GOTO 1830
1825 PRINT"Scrolls:"T(9)
1830 IF T(10)=0 GOTO 1840
1835 PRINT"Rings:"T(10)
1840 IF T(11)=0 GOTO 1850
1845 PRINT"Rods, Staves, Wands:"T(11)
1850 IF T(12)=0 GOTO 1860
1855 PRINT"Miscellaneous Magic:"T(12)
1860 IF T(13)=0 GOTO 1870
1865 PRINT"Armor & Shields:"T(13)
1870 IF T(14)=0 GOTO 1880
1875 PRINT"Swords:"T(14)
1880 IF T(15)=0 GOTO 1990
1885 PRINT"Miscellaneous Weapons:"T(15)
1990 PRINT
1995 RETURN
2000 REM key
2010 REM for t(x), totals
2015 REM x; 1=copper, 2=silver, 3=electrum, 4=gold, 5=platinum
2016 REM x; 6=gems, 7=jewelry, 8=potions, 9=scrolls, 10=rings
2017 REM x; 11=rsw, 12=miscmag, 13=armor&shields, 14=swords,
2018 REM x; 15=miscwep, 16=map
2019 REM
2020 REM for d(x,y,z), treasure type data
2025 REM x; 1=treas type "A", 2=B... 26=Z
2026 REM y; as per t(x) where x=1 to 7
2027 REM z; 1=%, 2=# of #ds, 3=s of #ds
2029 REM
2030 REM for g(x,y), gems
2032 REM x; 1=ornamental stones... 3=fancy stones... 6=huge gems
2034 REM y; 1=(>%) for group, 2=base value
2036 REM
2040 REM for j(x,y), jewelry
2042 REM x; jewelry class
2044 REM y; 1=(>%) for class, 2=#d, 3=ds, 4=multiplier
2900 REM
2910 REM
5000 REM data
5010 REM for d(x,y,z)
5020 DATA 25,1,6,30,1,6,35,1,6,40,1,10,25,1,4,60,4,10,50,3,10
5030 DATA 50,1,8,25,1,6,25,1,4,25,1,3,0,0,0,30,1,8,20,1,4
5040 DATA 20,1,12,30,1,6,10,1,4,0,0,0,0,0,0,25,1,6,20,1,3
5050 DATA 10,1,8,15,1,12,15,1,8,50,1,6,0,0,0,30,1,10,25,1,6
5060 DATA 5,1,10,25,1,12,25,1,6,25,1,8,0,0,0,15,1,12,10,1,8
5070 DATA 0,0,0,10,1,20,15,1,12,40,1,10,35,1,8,20,3,10,10,1,10
5080 DATA 0,0,0,0,0,0,0,0,0,50,10,4,50,1,20,30,5,4,25,1,10
5090 DATA 25,5,6,40,1,100,40,10,4,55,10
5095 DATA 6,25,5,10,50,1,100,50,10,4
5100 DATA 0,0,0,0,0,0,0,0,0,0,0,0,30,3,6,55,2,10,50,1,12
5110 DATA 100,3,8,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5120 DATA 0,0,0,100,3,6,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5130 DATA 0,0,0,0,0,0,100,2,6,0,0,0,0,0,0,0,0,0,0,0,0
5140 DATA 0,0,0,0,0,0,0,0,0,100,2,4,0,0,0,0,0,0,0,0,0
5150 DATA 0,0,0,0,0,0,0,0,0,0,0,0,100,1,6,0,0,0,0,0,0
5160 DATA 25,1,4,20,1,3,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5170 DATA 0,0,0,30,1,6,25,1,2,0,0,0,0,0,0,0,0,0,0,0,0
5180 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,50,1,4,0,0,0
5185 DATA 0,0,0,0,0,0,0,0,0,40,2,4,50,10,6,55,4,8,45,1,12
5190 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5200 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5210 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,90,10,8,80,5,6
5220 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5230 DATA 0,0,0,0,0,0,0,0,0,60,5,6,15,1,8,60,10,8,50,5,8
5240 DATA 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
5250 DATA 0,0,0,0,0,0,0,0,0,70,2,6,0,0,0,0,0,0,0,0,0
5260 DATA 20,1,3,25,1,4,25,1,4,30,1,4,30,1,6,55,10,6,50,5,6
5295 REM for g(x,y)
5300 DATA 0,10,25,50,50,100,70,500,90,1000,99,5000
5310 DATA 0,1,10,100,10,2,6,100,20,3,6,100,40,5,6,100
5315 REM for j(x,y)
5320 DATA 50,1,6,1000,70,2,4,1000,90,2,6,1000
5330 REM for mp(x)
5335 DATA 30,10,10,15,25,30,35,15,15,0
5340 DATA 0,0,0,0,0,0,0,0,40,50
5345 DATA 70,85,55,60,0,50
9998 PRINT:PRINT"Hasta la bye bye...."
9999 KEY ON:PRINT
10000 END
4. mfile.a
What follows in this section is the ASCII file, mfile.a, which
MEG.BAS reads in order to generate monster encounters. I've
selected monsters from the basic books which I've felt more or
less comfortable with. Being basically the non-killer variety
of GM, there are few devils, demons, monsters with lethal
poison or energy drain or petrification, etc... etc...
Again, you'll need to modify this file to suit your own
campaign. If you have any questions on how to do this after
examining the program, feel free to bug me.
One important note here. When you cut out and save this
section as mfile.a, make sure that there are no blank lines
in mfile.a or the program will likely screw things up.
-----------Cut here, leave no blank lines---------
Aarakocra
FF p8
d10
d
18
7
d3 d3 / wep
d8+2
28+2/hp
Afanc
MM2 p8
d1
0
8
6
5d4 / 3d4*2
15d8
4000+20/hp
Giant Ant
MM1 p7
d100
qqqs
16
3
d6
2d8
20+2/hp
Lion Ant
MM2 p10
d1
0+Treasure is Special
12
2
5d4
8d8
575+10/hp
Carnivorous Ape
MM1 p7
2d4
c
15
6
d4 d4 d8 +
5d8
170+5/hp
Aspis Drone
MM2 p10
2d10
f
13
3/2
d4 d4 / weps
6d8
300+6/hp
Atomie
MM2 p11
30d4
q+M
20
4
wep
d4
40+1/hp
Aurumvorax
MM2 p11
d1
0+Incidental Treasure
9
0
2d4 +
12d8
2700+16/hp
Babbler
FF p13
d4
b
15
6
d6 d6 d8
5d8
130+5/hp
Baboon
MM1 p8
10d4
0
18
7
d4
d8+1
20+2/hp
Baluchitherium
MM1 p8
d3
0
8
5
5d4 5d4
14d8
4200+18/hp
Banderlog
MM2 p13
4d6
0+Occasional Jewelry
15
6
d4+1
4d8
60+4/hp
Fire Bat
MM2 p16
d10+10
i
16
8
2d4
2d8
28+2/hp
Cave Bear
MM1 p9
d2
0
13
6
d8 d8 d12
6d8+6
475+8/hp
Gorilla Bear
FF p46
d6+1
0
15
4
d8 d8 +
4d8
85+4/hp
Northern Bear
MM2 p16
d6
0
12
6
d10 d10 2d6
8d8+8
900+12/hp
Giant Fire Beetle
MM1 p9
3d4
0
18
4
2d4
d8+2
20+2/hp
Giant Stag Beetle
MM1 p9-10
2d6
0
13
3
4d4 d10 d10
7d8
400+8/hp
Bull Behemoth
MM2 p18
d4
0
10
4
6d4
10d8+5
1600+15/hp
Behir
MM2 p18
d2
0+Treasure is Special
9
4
2d4&d4+1/d6*6
12d8
2850+16/hp
Black Pudding
MM1 p10
d4
0
10
6
3d8
10d8
1350+14/hp
Giant Bloodworm
FF p15
d4
q
13
4
d8
6d8
225+6/hp
Giant Bluebottle
MM2 p65
d10
0
16
6
d8
3d8
35+3/hp
Giant Boar
MM1 p11
2d4
0
13
6
3d6
7d8
225+8/hp
Bonesnapper
FF p15
d3
c
15
4
d8 d4
4d8
60+4/hp
Buffalo
MM1 p11
4d6
0
15
7
d8 d8
5d8
350+8/hp
Bugbear
MM1 p12
6d6
b+JKLM
16
5
2d4 / wep
3d8+1
135+4/hp
Bullywug
FF p16
10d8
jkmqqqqq
19
6
d2*2 d4+1/wep
d8
18+1/hp
Giant Bumblebee
MM2 p17
d1
0
13
5
d6 + Poison
6d8+4
400+8/hp
Bunyip
FF p17
d1
0
15
10
d6
5d8
90+5/hp
Centaur
MM1 p14
4d6
dit+MQ
15
5
d6 d6
4d8
85+4/hp
Huge Centipede
MM2 p24
5d6
0
20
9
---
d1
30+1/hp
Cheetah
MM2 p25
d4
0
16
5
d2 d2 2d4
3d8
65+3/hp
Clubnek
FF p19
2d4
0
16
8
d6 d6 d8
2d8
20+2/hp
Cooshee
MM2 p26
d8
0
16
5
d6+4
3d8+3
110+4/hp
Giant Crab
MM1 p15
2d6
0
16
3
2d4 2d4
3d8
35+3/hp
Giant Crane
MM2 p26
d20
0
16
5
d10
3d8
35+3/hp
Giant Crayfish
MM1 p15
d4
0
15
4
2d6 2d6
4d8+4
90+5/hp
Crimson Death
MM2 p32
d1
z
9
0/4
3d10
13d8
7050+18/hp
Crocodile
MM1 p15
3d8
0
16
5
2d4 d12
3d8
60+4/hp
Giant Crocodile
MM1 p15
2d6
0
13
4
3d6 2d10
7d8
400+8/hp
Giant Cyclops
Guildsman #3 p90
d4
a
8
2
2d8 2d8
14d8
5200+18/hp
Cyclopskin
MM2 p27
d8
c
15
3
wep+2
5d8
90+5/hp
Dakon
FF p22
6d10
e
18
5
d10 d10
d8+1
20+2/hp
Death Knight
FF p23
d1
0
12
0
wep
9d10
3700+16/hp
Blink Dog
MM1 p10
4d4
c
15
5
d6
4d8
170+5/hp
Death Dog
FF p23
5d10
0
16
7
d10 d10
2d8+1
105+3/hp
War Dog
MM1 p29
d10
0
16
6
2d4
2d8+2
35+3/hp
Wild Dog
MM1 p29
4d4
0
18
7
d4
d8+1
20+2/hp
Doombat
FF p27
d8
0
13
4
d6 d4
6d8+3
400+7/hp
Doppleganger
MM1 p29
3d4
e
15
5
d12
4d8
330+4/hp
Dragon Horse
MM2 p59
d1
0
12
0
d8 d8
8d8
1275+10/hp
Dragon Turtle
MM1 p35
d1
brstv
8
0
2d6 2d6 4d8
14d8
7300+18/hp
Dragonnel
MM2 p60
d4
0
12
3
d6 d6 4d4
8d8+4
600+12/hp
Dustdigger
MM2 p61
d20
0
15
4
d8+AC
4d8
165+4/hp
Giant Eagle
MM1 p37
d20
q
15
7
d6 d6 2d6
4d8
150+4/hp
Giant Eel
MM1 p36
d4
0
15
6
3d6
5d8
49+1/hp
Ettin
MM1 p40
d4
cy+O
10
3
2d8 3d6
10d8
1950+14/hp
Large Falcon
MM2 p64
d2
0+5% Chance of Shiny Object in Nest
19
5
d2 d2 1
d8
25+1/hp
Firenewt
FF p36
10d10
f+KM
16
5
wep
2d8+2
90+3/hp
Firetoad
FF p38
d6
c
15
10
hp-dmg
4d8+1
165+5/hp
Flind
FF p39
2d12
a
15
5
d6 / d4
2d8+3
35+3/hp
Forlarren
FF p39
d1
0
16
2
d4 d4
3d8
90+3/hp
Formian Worker
MM2 p66
10d4
0
18
3
d4
d8+1
20+2/hp
Giant Frog
MM1 p41
5d8
0
17
7
d6
2d8
45+3/hp
Froghemoth
MM2 p67
d1
0
7
2/4/6
5d10/(d4+4)*4
16d8
8100+20/hp
Frost Man
FF p40
d1
c
15
5
wep
4d8
125+4/hp
Giant Gar
MM1 p42
d6
0
12
3
5d4
8d8
550+10/hp
Gargoyle
MM1 p42
2d8
c+10*M
15
5
d3 d3 d6 d4
4d8+4
165+5/hp
Gelatinous Cube
MM1 p43
d1
jklmnq
15
8
2d4
4d8
150+4/hp
Cliff Giant
Guildsman #3 p88
d6
e
9
3
6d6
12d8
2850+16/hp
Fire Giant
MM1 p44
d8
e
9
3
5d6 / 2d10
11d8+4
2700+16/hp
Fog Giant
FF p42
d4
e
8
1
4d6
14d8
3950+18/hp
Formorian Giant
MM2 p68
d4
dqqqqqqqqqq
9
3
4d8
13d8+2
2750+18/hp
Frost Giant
MM1 p44
d8
e
10
4
4d6 / 2d10
10d8+3
2250+14/hp
Hill Giant
MM1 p45
d10
d
12
4
2d8
8d8+2
1400+12/hp
Mountain Giant
FF p42
d4
e
9
4
4d10
12d8
2850+16/hp
Stone Giant
MM1 p45
d8
d
12
0
3d6 / 3d10
9d8+2
1800+14/hp
Gibbering Mouther
MM2 p69
d1
q
15
1
1*6 +
4d8+3
210+5/hp
Gibberling
FF p43
40d10
d
18
10
d8
d8
14+1/hp
Gnoll
MM1 p46
20d10
dqqqqqs+LM
16
5
2d4 or wep
2d8
28+2/hp
Goblin
MM1 p47
40d10
c+K
20
6
d6 / wep
d6+1
10+1/hp
Gorilla
MM1 p7
d4
0
15
6
d3 d3 d6 +
4d8+1
130+5/hp
Grell
FF p46
d1
0
15
4
d4*10 d6
5d8
840+5/hp
Grimlock
FF p48
20d10
b+KLM
16
5
d6 / wep
2d8
28+2/hp
Grippli
MM2 p71
5d6
qqqqi
18
9
d4 / wep
d8+1
45+2/hp
Gryph
FF p48
d6
0
16
6
2d6
3d8
50+3/hp
Hippocampus
MM1 p51
2d4
0
15
5
d4
4d8
60+4/hp
Hippopotamus
MM1 p52
2d6
0
12
6
2d6 / 3d6
8d8
375+6/hp
Hoar Fox
FF p50
d6
0+Pelt Worth 100gp
16
6
d6 / (2d6)
2d8
28+2/hp
Hobgoblin
MM1 p52
20d10
dqqqqq+J & M
18
5
d8 / wep
d8+1
20+2/hp
Hook Horror
FF p51
2d6
p
15
3
d8 d8
5d8
90+5/hp
Giant Hornet
FF p51
d1
0
15
2/4
d4 +
5d8
165+5/hp
Hell Hound
MM1 p51
2d4
c
13
4
d10
7d8
250+8/hp
Yeth Hound
MM2 p129
4d4
0
16
0
2d4
3d8+3
235+4/hp
Hyaenodon
MM1 p54
2d4
0
15
7
3d4
5d8
90+5/hp
Hybsil
MM2 p76
10d6
i
20
7
d4 / wep
d7
22+1/hp
Hyena
MM1 p54
2d6
0
16
7
2d4
3d8
35+3/hp
Invisible Stalker
MM1 p55
d1
0
12
3/1
4d4
8d8
1090+10/hp
Jackalwere
MM1 p56
d4
c
15
4
2d4
4d8
800+4/hp
Jaguar
MM1 p56
d2
0
15
6
d3 d3 d8 +
4d8+1
205+5/hp
Jermlaine
FF p53
12d4
cqqqqqst+(O+Q)/10
20
7
d2 / d4
d4
7+1/hp
Kech
MM2 p78
2d4
b
15
4
d4+1 d4+1 d6
5d8
205+5/hp
Killmoulis
FF p57
d3
k
20
6
---
d4
9+1/hp
Kobold
MM1 p57
40d10
oqqqqq+J
20
7
d4 / wep
d4
5+1/hp
Kraken
MM2 p79
d1
grs
7
5/0
2d6*2 2d4*d3+3 5d4
20d8
16900+30/hp
Leopard
MM1 p60
d2
0
16
6
d3 d3 d6 +
3d8+2
150+4/hp
Leucrotta
MM1 p60
d4
d
13
4
3d6
6d8+1
475+8/hp
Mountain Lion
MM1 p61
d2
0
16
6
d3 d3 d6 +
3d8+1
110+4/hp
Sea Lion
MM1 p86
3d4
b
13
5/3
d6 d6 2d6
6d8
150+6/hp
Spotted Lion
MM1 p61
2d4
0
13
5/6
d4 d4 d12 +
6d8+2
300+6/hp
Fire Lizard
MM1 p61
d4
bqqqqqqqqqqst
10
3
d8 d8 2d8
10d8
1350+14/hp
Giant Lizard
MM1 p61
2d6
0
16
5
d8
3d8+1
125+4/hp
Subterranean Lizard
MM1 p61-2
d6
opqqqqq
13
5
2d6
6d8
350+6/hp
Lizard King
FF p61
d1
e
12
3
5d4
8d8
550+10/hp
Lizard Man
MM1 p62
10d4
d
16
5
d2 d2 d8
2d8+1
35+3/hp
Locathah
MM1 p62
20d10
a
16
6
wep
2d8
20+2/hp
Magma Para-Elemental
MM2 p98
d1
0
9
3
4d6
12d8
2850+15/hp
Magman
MM2 p82
2d12
0
16
6
3d8 / d8
2d8
97+2/hp
Margoyle
MM2 p83
2d4
c+Q
13
2
d6 d6 2d4 2d4
6d8
350+6/hp
Fire Mephit
FF p64
d1
0+2d6 P.P.
16
5
(d3+1)*2
3d8+1
150+4/hp
Lava Mephit
FF p64
d1
0+d10 P.P.
16
6
(d8+1)*2
3d8
105+3/hp
Smoke Mephit
FF p65
d1
0+d10 P.P.
16
4
d2*2
3d8
105+3/hp
Steam Mephit
FF p65
d1
0+3d6 P.P.
16
7
(d4+1)*2
3d8+3
175+4/hp
Merman
MM1 p70
20d10
cr
18
7
wep
d8+1
20+2/hp
Mimic
MM1 p70
d1
0
12
7
3d4
9d8
1300+12/hp
Minotaur
MM1 p71
d8
c
13
6
wep & 2d4/d4
6d8+3
400+8/hp
Mite
FF p66
6d4
c
20
8
d3
d7
5+1/hp
Muckdweller
MM2 p93
5d4
jklmn+Q
20
6
d2
d4
7+1/hp
Mustard Jelly
MM2 p77
d1
0
12
4
5d4 / 2d4 2d4
7d8+14
825+18/hp
Narwhale
MM2 p95
d6
0
13
6
6d4
5d8+5
190+6/hp
Nightmare
MM1 p74
d1
0
13
-4/-6
2d4 (2d4+2)*2
6d8+6
600+8/hp
Norker
FF p68
3d10
e
18
3
d3 d6
d8+2
20+2/hp
Ochre Jelly
MM1 p75
d3
0
13
8
3d4
6d8
150+6/hp
Giant Octopus
MM1 p75
d3
r
12
7
2d4*6 2d6
8d8
550+10/hp
Ogre
MM1 p75
2d10
qbs+M*10
15
5
d10 / wep
4d8+1
90+5/hp
Ogrillon
FF p70
5d6
bs+M
16
6
d6+1 d6+1
2d8
28+2/hp
Domestic Oliphant
MM2 p96
d8
0
10
4
(3d4)*4
10d8+5
600+12/hp
Wild Oliphant
MM2 p96
d8
0
12
4
(3d4)*4
8d8+4
600+12/hp
Orc
MM1 p76
30d10
cosqqqqqqqqqq+L
19
6
d8 / wep
d8
10+1/hp
Osquip
FF p70
2d12
d
16
7
2d6
3d+1
60+4/hp
Pech
MM2 p99
5d4
0+Gems & Jewelry in Lair
15
3
wep+3
4d8
240+4/hp
Pegasus
MM1 p78
d10
0
15
6
d8 d8 d3
4d8
60+4/hp
Pernicon
FF p72
4d10
0+Treasure is Special
20
3
d3
d4
7+1/hp
Giant Pike
MM1 p78
d8
0
15
5
4d4
4d8
85+4/hp
Pteranodon
MM1 p27
3d6
0
16
7
2d4
3d8+3
85+4/hp
Purple Worm
MM1 p80
d2
bqqqqqx
8
6
2d12 2d4
15d8
4900+20/hp
Quaggoth
FF p74
2d12
a
18
6
d4 d4 / wep
d8+2
28+2/hp
Quickling
MM2 p103
4d4
opqx
18
-3
d6 d6 d6
d12
200+3/hp
Quipper
FF p74
5d10
0
20
8
d2
d4
5+1/hp
Qullan
FF p74
d6
0+Treasure is Special
16
10
2d4+3
2d8
73+2/hp
Giant Ram
MM1 p81
2d4
0
15
6
2d6
4d8
85+4/hp
Giant Rat
MM1 p81
5d10
c
20
7
d3
d4
7+1/hp
Giant Raven
MM2 p105
4d4
0+1 in 6 Chance of Small Gem in Nest
16
4
d4+2
3d8+2
60+4/hp
Woolly Rhinoceros
MM1 p82
d4
0
10
5
2d6
10d8
1350+14/hp
Roc
MM1 p82
d2
c
7
4
3d6*2 / 4d6
18d8
5000+25/hp
Rockworm
FF p87
d2
0+10-60 Gems (base 10gp) in Group
16
2
4d8 / 2d6
3d8
65+3/hp
Rothe
FF p76
2d10
0
16
7
d3 d3 d8
2d8
20+2/hp
Sahuagin
MM1 p84
20d4
iopqqqqqqqqqqxy+N
16
5
wep
2d8+2
35+3/hp
Salamander
MM1 p85
d4+1
f
12
5/3
wep 2d6
7d8+7
825+10/hp
Sandling
MM2 p106
d1
0
15
3
2d8
4d8
85+4/hp
Giant Scorpion
MM1 p85
d4
d
13
3
d10 d10 d4
5d8+5
650+6/hp
Freshwater Scrag
MM2 p121-2
d6
c
13
3
d4+1 d4+1 3d4
5d8+5
400+8/hp
Saltwater Scrag
MM2 p121-2
d8
d
13
2
d4 d4 d8+8
6d8+12
900+12/hp
Scum Creeper
MM2 p107
2d12
0
19
8
d1
2d4
14+1/hp
Giant Sea Horse
MM1 p86
d20
0
16
7
d4/d4+1/2d4
2d8
20+4/hp
Selkie
MM2 p107
6d4+6
r+Magic(A) in Lair
16
5
d6 / wep
3d8+3
75+4/hp
Shadow
MM1 p86
2d10
f
16
7
d4+1
3d8+3
255+4/hp
Shambler
MM1 p87
d3
btx
10
0
2d8 2d8
10d8
1800+10/hp
Skeleton
MM1 p87
3d10
0
19
7
d6
d8
14+1/hp
Animal Skeleton
MM2 p109
2d10
0
20
8
d4
d7
10+1/hp
Skeleton Elite
Guildsman #3 p91
d10
0
15
4
d8 d8
5d8
205+5/hp
Skulk
FF p80
d8
a
16
7
wep
2d8
36+2/hp
Giant Slug
MM1 p88
d1
0
9
8
d12
12d8
2000+16/hp
Fire Snake
FF p38
d6
q
16
6
d4
2d8
73+2/hp
Snapper-Saw
MM2 p66
d2
0
15
4 (stalks) / 7 (leaves) / 9 (bush proper)
(d4+1)*(d4+2)
5d8
165+5/hp
Snow Mole
Guildsman #3 p92
d3
c
8
1
2d10
14d8
3000+18/hp
Snyad
FF p83
d8
j
20
-4
---
d7
7+1/hp
Huge Solifugid
MM2 p112
d6
qs
13
5
3d4
5d8+5
225+6/hp
Giant Spider
MM1 p90
d8
c
15
4
2d4
4d8+4
315+5/hp
Hyper-Spider
Guildsman #3 p92
d1
a
7
0
d8*8 3d6
18d8
6550+25/hp
Spined Devil
MM2 p49
d4+1
0
16
3
wep / d4 d4
3d8+3
240+4/hp
Giant Squid
MM1 p92
d1
a
9
7/3
d6*8 5d4
12d8
2000+16/hp
Giant Black Squirrel
MM2 p114
d12
0
18
6
d3
d8+1
20+2/hp
Giant Stag
MM1 p92
d2
0
15
7
4d4 / d4*2
5d8
90+5/hp
Stench Kow
MM2 p115
15d4
0
16
2
2d4
3d8+3
150+4/hp
Stirge
MM1 p92
3d10
d
15
8
d3
d8+1
36+2/hp
Stone Guardian
MM2 p115
d4
0
15
2
d8+1 d8+1
4d8+4
550+8/hp
Giant Strider
FF p42
d6
0
16
4
d8 / d10
2d8
73+2/hp
Stunjelly
FF p84
d1
0+Treasure is Special
15
8
2d4
4d8
125+4/hp
Swordfish
MM2 p117
d8
0
16
6
3d4
2d8+2
35+3/hp
Tabaxi
FF p86
2d4
0+5% Chance of Magical Weapon in Group
16
6
d3 d3 d3
2d8
20+2/hp
Taer
MM2 p117
d20+10
0+Teeth Horns Stone Idols & 15% Captured Loot (10% Magic)
15
4
d6 d4*2 / wep
3d8+6
150+4/hp
Tasloi
MM2 p118
10d10
qqqqq
19
6
d3 d3 / wep
d8
10+1/hp
Giant Soldier Termite
MM2 p118
3d6
0
16
2/8
d4
2d8+2
50+3/hp
Giant Worker Termite
MM2 p118
6d10
0
18
2/10
d2
d8+2
20+2/hp
Thessalhydra
MM2 p119
d1
0
9
0
d6*8 d12 d20
12d8
5800+16/hp
Thri-kreen
MM2 p119
2d6
q
13
5
d4*4 d4+1 / wep*3
6d8+3
800+8/hp
Thunderherder
MM2 p120
10d10
0
13
3
---
7d8
350+8/hp
Giant Tick
MM1 p94
3d4
0
16
3
d4
3d8
105+2/hp
Sabre-Tooth Tiger
MM1 p94
d2
0
11
6
(d4+1)*2 2d6 +
7d8+2
550+10/hp
Titanothere
MM1 p95
d12
0
9
6
2d8
12d8
2000+16/hp
Giant Toad
MM1 p95
d12
0
16
6
2d4
2d8+4
50+3/hp
Triceratops
MM1 p28
2d4
0
7
2/6
d8 d12 d12
16d8
4000+20/hp
Triton
MM1 p96
10d6
crstx
16
5/4
wep
3d8
105+3/hp
Troglodyte
MM1 p97
10d10
a
16
5
d3 d3 d4+1
2d8
36+2/hp
Troll
MM1 p97
d12
d
13
4
d4+4 d4+4 2d6
6d8+6
525+8/hp
Giant Troll
FF p90
d12
c
12
4
2d8/(d6+1)*2
8d8
725+10/hp
Giant Two-Headed Troll
FF p90
d3
dq
10
4
d6 d6 d10 d10
10d8
1800+14/hp
Tumblewolves
Guildsman #3 p93
d10
i
13
5
d6 d6 d10
6d8
245+5/hp
Tunnel Worm
MM2 p128
d6
mnq
12
4
2d8
9d8+3
1350+14/hp
Giant Snapping Turtle
MM1 p97
d4
0
10
0/5(2)
6d4
10d8
1950+14/hp
Tyrannosaurus Rex
MM1 p28
d2
0
7
5
d6 d6 5d8
18d8
6550+25/hp
Unicorn
MM1 p98
d4+1
x
13
2
d6 d6 d12
4d8+4
400+5/hp
Black Urchin
FF p92
d6
0+10d10 G.P. Gem
17
4
d6
d8+1
28+2/hp
Green Urchin
FF p93
d4
0+40d10 G.P. Gem
14
3
d6+1 d6+1
2d8+1
50+3/hp
Red Urchin
FF p93
d4
0+90d10 G.P. Gem
13
2
(d4+1)*3
3d8+1
85+4/hp
Uropygus
MM2 p100
d2
i
15
2
d8 d8 2d4
4d8+4
170+5/hp
Vampire
MM1 p99
d4
f
12
1
d6+4
8d8+3
3800+12/hp
Verme
MM2 p124
d1
0
7
3/5
7d4
18d8+18
8550+25/hp
Vilstrak
MM2 p124
2d10
c
20
2
d4+1 d4+1
d6
7+1/hp
Vodyanoi
FF p93
d3
g
12
2
3d4 3d4 d10
8d8
650+10/hp
Volt
FF p94
2d12
0
16
3
d4 (2d6)
2d8+1
50+3/hp
Giant Vulture
MM2 p125
2d6
0
16
7
d4
2d8+1
20+2/hp
Giant Wasp
MM1 p99
d20
qqqqqqqqqqqqqqqqqqqq
15
4
2d4 d4
4d8
320+4/hp
Wemic
MM2 p126
2d8
b
13
6
d4 d4 wep
5d8+8
200+7/hp
Witherstench
FF p95
3d4
b
16
7
d6 d6
2d8+2
65+3/hp
Winter Wolf
MM1 p101
2d4
i
13
5
2d4
6d8
245+5/hp
Worg
MM1 p101
3d4
0
15
6
2d4
4d8+4
90+5/hp
Xorn
MM1 p102
d4
opqqqqqxy
12
-2
d3*3 6d4
7d8+7
1275+10/hp
Yeti
MM1 p103
d6
d
15
6
d6 d6
4d8+4
435+5/hp
Zombie
MM1 p103
3d8
0
16
8
d8
2d8
20+2/hp
Zombie Monster
MM2 p131
d6
0
13
6
4d4
6d8
150+6/hp
----------cut here, leave no blank lines-------
5. LaTeXed Monster Chart
When using the program, I've often found it rather tiresome
to keep looking up the names of monsters which it recognizes.
The following LaTeX document should solve that problem for
those among you who have access to LaTeX. I can make the
following document available in PostScript upon request.
\documentstyle{article}
\setlength{\oddsidemargin}{-.5in}
\setlength{\textwidth}{7.5in}
\setlength{\topmargin}{-1.25in}
\setlength{\textheight}{10in}
\begin{document}
\parindent=30pt
\title{Monster Chart}
\author{for MEG.BAS}
\date{jimv@ucrmath.ucr.edu}
\maketitle
{\small
\begin{center}
\begin{tabular}{lllll}
Aarakocra&
Afanc&
Giant Ant&
Lion Ant&
Carnivorous Ape\\
Aspis Drone&
Atomie&
Aurumvorax&
Babbler&
Baboon\\
Baluchitherium&
Banderlog&
Fire Bat&
Cave Bear&
Gorilla Bear\\
Northern Bear&
Giant Fire Beetle&
Giant Stag Beetle&
Bull Behemoth&
Behir\\
Black Pudding&
Giant Bloodworm&
Giant Bluebottle&
Giant Boar&
Bonesnapper\\
Buffalo&
Bugbear&
Bullywug&
Giant Bumblebee&
Bunyip\\
Centaur&
Huge Centipede&
Cheetah&
Clubnek&
Cooshee\\
Giant Crab&
Giant Crane&
Giant Crayfish&
Crimson Death&
Crocodile\\
Giant Crocodile&
Giant Cyclops&
Cyclopskin&
Dakon&
Death Knight\\
Blink Dog&
Death Dog&
War Dog&
Wild Dog&
Doombat\\
Doppleganger&
Dragon Horse&
Dragon Turtle&
Dragonnel&
Dustdigger\\
Giant Eagle&
Giant Eel&
Ettin&
Large Falcon&
Firenewt\\
Firetoad&
Flind&
Forlarren&
Formian Worker&
Giant Frog\\
Froghemoth&
Frost Man&
Giant Gar&
Gargoyle&
Gelatinous Cube\\
Cliff Giant&
Fire Giant&
Fog Giant&
Formorian Giant&
Frost Giant\\
Hill Giant&
Mountain Giant&
Stone Giant&
Gibbering Mouther&
Gibberling\\
Gnoll&
Goblin&
Gorilla&
Grell&
Grimlock\\
Grippli&
Gryph&
Hippocampus&
Hippopotamus&
Hoar Fox\\
Hobgoblin&
Hook Horror&
Giant Hornet&
Hell Hound&
Yeth Hound\\
Hyaenodon&
Hybsil&
Hyena&
Invisible Stalker&
Jackalwere\\
Jaguar&
Jermlaine&
Kech&
Killmoulis&
Kobold\\
Kraken&
Leopard&
Leucrotta&
Mountain Lion&
Sea Lion\\
Spotted Lion&
Fire Lizard&
Giant Lizard&
Subterranean Lizard&
Lizard King\\
Lizard Man&
Locathah&
Magma Para-Elemental&
Magman&
Margoyle\\
Fire Mephit&
Lava Mephit&
Smoke Mephit&
Steam Mephit&
Merman\\
Mimic&
Minotaur&
Mite&
Muckdweller&
Mustard Jelly\\
Narwhale&
Nightmare&
Norker&
Ochre Jelly&
Giant Octopus\\
Ogre&
Ogrillon&
Domestic Oliphant&
Wild Oliphant&
Orc\\
Osquip&
Pech&
Pegasus&
Pernicon&
Giant Pike\\
Pteranodon&
Purple Worm&
Quaggoth&
Quickling&
Quipper\\
Qullan&
Giant Ram&
Giant Rat&
Giant Raven&
Woolly Rhinoceros\\
Roc&
Rockworm&
Rothe&
Sahuagin&
Salamander\\
Sandling&
Giant Scorpion&
Freshwater Scrag&
Saltwater Scrag&
Scum Creeper\\
Giant Sea Horse&
Selkie&
Shadow&
Shambler&
Skeleton\\
Animal Skeleton&
Skeleton Elite&
Skulk&
Giant Slug&
Fire Snake\\
Snapper-Saw&
Snow Mole&
Snyad&
Huge Solifugid&
Giant Spider\\
Hyper-Spider&
Spined Devil&
Giant Squid&
Giant Black Squirrel&
Giant Stag\\
Stench Kow&
Stirge&
Stone Guardian&
Giant Strider&
Stunjelly\\
Swordfish&
Tabaxi&
Taer&
Tasloi&
Giant Soldier Termite\\
Giant Worker Termite&
Thessalhydra&
Thri-kreen&
Thunderherder&
Giant Tick\\
Sabre-Tooth Tiger&
Titanothere&
Giant Toad&
Triceratops&
Triton\\
Troglodyte&
Troll&
Giant Troll&
Giant Two-Headed Troll&
Tumblewolves\\
Tunnel Worm&
Giant Snapping Turtle&
Tyrannosaurus Rex&
Unicorn&
Black Urchin\\
Green Urchin&
Red Urchin&
Uropygus&
Vampire&
Verme\\
Vilstrak&
Vodyanoi&
Volt&
Giant Vulture&
Giant Wasp\\
Wemic&
Witherstench&
Winter Wolf&
Worg&
Xorn\\
Yeti&
Zombie&
Zombie Monster&
&\\
\end{tabular}
\end{center}}
\thispagestyle{empty}
\end{document}
6. One Final Word
Of course, this program is far from professional. For those of you
looking for something better, I might suggest SSI's first DM's
Assistant program, which I heard was decent, though it's been off
the shelves and out of print for many years (no, i don't have a copy).
Last I heard, however, SSI had an account on Compuserve which you can
reach by emailing 76711.250@compuserve.com
One final note. This program and those like it have always had, in my
mind at least, one common failing. They promote roll-playing rather
than role-playing, the former being a very easy rut to fall into.
If you decide to use MEG or any of its kin, please remember, never
let a monster do the work of an evil genius :-) (yeah, it's a stolen
quote, but so what) Til later....
_ /|
\`o_O'
( ) <--- jimv@ucrmath.ucr.edu
U ucsd!ucrmath!jimv (uucp)
Aachk!
Phft! Ftp!